Hướng dẫn tạo tập tin sao lưu và gửi tập tin cho người quản trị qua Gmail. Bên dưới là mô hình cho mọi người dể hình dung:



Bắt đầu thôi nào!
Bước 1: Tạo Script. Từ giao diện Winbox->System->Scripts. Sau đó nhấn vào dấu [+] để thêm Script mới.
- Đặt tên cho Script ở phần Name: gmailbk
- Phần Source cho phép chúng ta thao tác các dòng lệnh để thực hiện công việc trên. Mọi người sao chép code bên dưới và dán vào phần Source này.
[i]***Lưu ý:
- Ở phần #Information Gmail: Khai báo các thông tin về địa chỉ Gmail - là thông tin Gmail người gửi. Có nghĩa là bản thân Mikrotik Router sở hữu Gmail này để có thể gửi mail cho người quản trị. Tuy nhiên, có thể gửi dùng duy nhất 1 mail cho người gửi và người nhận.

Code:
:local CurDate [/system clock get date] 
:local CurTime [/system clock get time] 
:local GDate [/system clock get date]
:local GDay [ :pick $GDate 4 6 ]
:local GMonth [ :pick $GDate 0 3 ]
:local GYear [ :pick $GDate 7 11 ]
:local GResult "$GDay $GMonth $GYear"
#Infomation Mikrotik-Router
:local Name [/system identity get name]
:local Model [/system routerboard get model]
:local Seri [/system routerboard get serial-number]
:local DDNS [/ip cloud get dns-name]
:local IPPulic [/ip cloud get public-address]
:local Version [/system resource get version]
#Information Gmail
:local GmailSMTP
:set GmailSMTP [:resolve "smtp.gmail.com"];
:local GmailID "sentmail@switch-router.com"
:local GmailUser "sentmail@switch-router.com"
:local GmailPWD "P@ssw0rd"
:local GmailPort "587"
/tool e-mail set address=$GmailSMTP port=$GmailPort start-tls=yes from=$GmailID user=$GmailUser password=$GmailPWD
:local ToAddr "sadmin@switch-router.com"
:local BackupConf ([/system identity get name].".backup")
:local ExportConf ([/system identity get name].".rsc")
:log info "---------------SaoThienVuong Backup And Sent To Gmail---------------"
:log info message="Create backup file(1/2).";
/system backup save name=$BackupConf
:delay 5s;
:log info message="File Backup Name: $BackupConf";
:log info message="-->Backup Finished.";
:log info message="Create config file (2/2).";
/export compact file=$ExportConf
:delay 5s;
:log info message="File Config Name: $ExportConf";
:log info message="-->Export Finished.";
:log info message="Start Sent Config File via Mail: $ToAddr"
:log info message="Sending............"
:local fileall {$BackupConf;$ExportConf}
/tool e-mail send to=$ToAddr subject="Configuration BACKUP of $GResult-Mikrotik Name: $Name"  body="Name:$Name, Version: $Version, Model:$Model, Serial:$Seri, Cloud:$DDNS, IPWAN:$IPPulic"  file=$fileall start-tls=yes;
:delay 20s;
/file remove $BackupConf
/file remove $ExportConf
/tool e-mail set address="" from="" user="" password="" port=0 start-tls=no
:log info "Remove Information Gmail and File Local."
:log info "----------ALL DONE----------"
:log info "Sao Thien Vuong"
Bước 2: Đặt lịch khởi chạy Script trên vào 8h00 sáng Chủ Nhật hàng tuần.
Từ giao diện Winbox->System->Scheduler. Sau đó nhấn vào dấu [+] để thêm lịch mới.
– Đặt tên cho lịch ở trường Name. Ví dụ đặt tên cho lịch là scheduler-gmailbk
Start Date: khai báo ngày/tháng/năm bắt đầu khởi chạy script. Lưu ý chọn ngày rơi vào chủ nhật nhé. Ví dụ [/b]Chủ nhật ngày 19 tháng 07 năm 2020[/b] thì sẽ khai báo như sau: [/b]jul/19/2020[/b]
Start Time: khai báo giờ/phút/giây bắt đầu khởi chạy script. Trong ví dụ này là lúc 8 giờ thì khai báo như sau: 08:00:00
Interval: thời gian việc khởi chạy script được lặp lại. Trong ví dụ này thì 7 ngày vì 7 ngày sau thì lại đến đúng Chủ Nhật. Khai báo như sau: 7d 00:00:00
On Event: khai báo tên script sẽ được khởi chạy, cụ thể hơn chính là tên lúc nãy chúng ta đặt ở phần script, trong ví dụ này script được khởi chạy với tên là gmailbk.

Bước 3: Kiểm tra
Kiểm tra log trên Mikrotik Router.



Quản trị viên nhận được mail thông báo kèm với các thông tin về thiết bị.



Thật đơn giản đúng không nào, Chúc mọi người thành công!