Phn phối thiết bị mạng MikroTik tại Việt Nam
Results 1 to 3 of 3

Thread: Cấu hnh load balancing v failover trn thiết bị router Mikrotik RB1100AHx2

  1. #1
    Administrator
    Join Date
    May 2015
    Posts
    66

    Cấu hnh load balancing v failover trn thiết bị router Mikrotik RB1100AHx2

    Thiết bị router hotspot Mikrotik RB1100AHx2 l thiết bị router chịu tải lớn, tnh năng cao cấp, gi thnh hợp l, ph hợp cho doanh nghiệp, trường học, điểm truy cập wifi cng cộng, .... c yu cầu thiết bị router mạnh mẻ, load balancing, failover trn nhiều kết nối WAN - Internet để phục vụ Internet tốc độ cao cho người dng.

    Bi hướng dẫn sau đy hướng được viết dựa trn cấu hnh load balancing v failover trn 3 kết nối WAN, trn thiết bị router Mikrotik RB1100AHx2, được chng ti triển khai cho 1 điểm truy cập wifi cng cộng của khch hng sử dụng sản phẩm v dịch vụ của cng ty Sao Thin Vương.

    Hiện trạng của khch hng:

    - Khch hng c 5 đường Internet tốc độ cao.
    - Thiết bị router nh mạng cung cấp, thiết bị pht sng wifi SOHO (Small Office and Home), do đ, kết nối wifi khng đảm bảo.
    - Cao điểm, c thể ln đến 300 người dng truy cập Internet đồng thời.

    Yu cầu của khch hng:

    - Load balancing v failover trn 3 đường kết nối Internet ny, c thể tăng ln 5 kết nối WAN tốc độ cao nếu cần.
    - Cung cấp kết nối wifi ổn định, tốc độ cao cho người dng wifi cng cộng của khch hng.

    Với hiện trạng v yu cầu trn, chng ti đề xuất trang bị thiết bị wifi chuyn dụng, thay thế cc thiết bị wifi SOHO m khch hng đang sử dụng.

    Trang bị thiết bị router Mikrotik RB1100AHx2 c khả năng chịu tải ln đến 500 kết nối Internet đồng thời, 13 Gigabit Interface, c thể load balancing, failover ln đến 12 đường WAN - Internet.

    Bn dưới l m hnh đấu nối thiết bị:



    Tiếp theo l chi tiết cấu hnh thiết bị router Mikrotik RB1100AHx2 load balancing v failover trn 3 kết nối WAN - Internet.

    Với thiết bị router Mikrotik, chng ta c nhiều phương n để load balancing v failover cho kết nối WAN, ở đy, chng ti triển khai theo phương thức gọi l PCC (Per Connection Classifier). Với phương thức ny, balancing trn cc kết nối WAN theo cc kết nối (connection).

    Đầu tin chng ta cần ch rằng, interface bridge trn router Mikrotik được thiết kế để lm cấu nối cho traffic ở Layer 2, do đ, giao tiếp bridge ny l kết nối logic để vận chuyển traffic Layer 2 giữa cc cổng của thiết bị router Mikrotik. Mặc định traffic ny giao tiếp bridge sẽ khng được xử l bởi cc rule của firewall hoạt động ở Layer 3. Để bắt buộc Layer traffic trn brigde được xử l bởi cc rule của firewall ở Layer 3, chng ta phải tường mnh khai bo với lệnh sau:

    Code:
    /interface bridge settings
    set use-ip-firewall=yes
    Trong trường hợp của ta traffic trn cc cổng khai bo l WAN được đng gi với giao thức PPPoE, cũng cần tường minh cho php đi qua cc rule của firewall ở Layer 3.

    Code:
    /interface bridge settings
    set use-ip-firewall-for-pppoe=yes
    Cc traffic của nội bộ mạng LAN qua router Mikrotik khng cần phải xử l bởi cc rule của firewall. Do đ, chng ta cần khai bo rule đầu tin cho tất cả traffic của nội bộ mạng LAN bypass cc rule của firewall.

    Code:
    /ip firewall mangle
    add chain=prerouting dst-address=192.168.100.0/24 in-interface=bridge action=accept
    Lệnh trn thực hiện ở chain pre-routing, do đ, traffic được xử l trước khi mọi quyết định định tuyến gi tn xảy ra đối với cc traffic đến router Mikrotik v traffic đang được forward bởi router Mikrotik. Rule trn kiểm tra mọi traffic c đch đến l mạng LAN (192.168.100.0/24) v interface tiếp nhận traffic trong trường hợp ny l bridge - giao tiếp cầu nối cho traffic cc cổng LAN của router Mikrotik. Action "accept" với mục đch dừng khng xử l traffic ny với cc rule kế tiếp sau. Để bắt traffic đi qua cc rule bn dưới tiếp theo, cần khai bo trường "passthrough=yes".

    Với mỗi interface WAN, cc traffic từ Internet vo WAN no cần phải đi ra WAN đ, nếu khng, kết nối sẽ bị gin đoạn - treo. Đặc biệt ch khi cần publish cc dịch vụ từ mạng LAN ra Internet như Web service, FTP, Email service... hoặc cc traffic khởi tạo từ Internet vo LAN như: SSH, VPN, ....

    Cc traffic vo router Mikrotik sẽ qua chain input v traffic rời router Mikrotik sẽ qua chain output. Chng ta sẽ sử dụng 2 bộ rule, một cho chain input v một cho chain output cho mỗi interface WAN m ta muốn load balancing v failover. Trong tường hợp ny, chng ta cần load balancing v failover trn 3 kết nối WAN.

    Bn dưới l cc mangle rule để xc định traffic khởi tạo từ Internet vo cc interface WAN v đnh dấu (new-connection-mark) cc traffic ny với interface WAN m n vo

    Code:
    /ip firewall mangle
    add chain=input  in-interface=pppoe-out1 connection-mark=no-mark action=mark-connection new-connection-mark=WAN1 passthrough=no
    add chain=input  in-interface=pppoe-out2 connection-mark=no-mark action=mark-connection new-connection-mark=WAN2 passthrough=no
    add chain=input  in-interface=pppoe-out3 connection-mark=no-mark action=mark-connection new-connection-mark=WAN3 passthrough=no
    Như vậy, cc kết nối khởi tạo từ Internet (new-connection) được đnh dấu với WAN1, WAN2, hoặc WAN3 tương ứng interface WAN m traffic đi vo. Tiếp theo, chng ta cần đảm bảo cc kết nối ny sẽ ra đng interface WAN m n đ khởi tạo vo. Chng ta thực hiện điều ny ở chain output v dng routing-mark để định tuyến gi tin theo đng bảng định tuyến m ta sẽ khai bo sau.

    Code:
    /ip firewall mangle
    add chain=output  out-interface=pppoe-out1 connection-mark=WAN1 action=mark-routing new-routing-mark=WAN1 passthrough=no
    add chain=output  out-interface=pppoe-out2 connection-mark=WAN2 action=mark-routing new-routing-mark=WAN2 passthrough=no
    add chain=output  out-interface=pppoe-out3 connection-mark=WAN3 action=mark-routing new-routing-mark=WAN3 passthrough=no
    Tiếp theo, chng ta sẽ thực hiện load balancing bằng phương thức PCC để cn bằng tải kết nối từ mạng nội bộ LAN ra 3 interface WAN m ta c bằng cc rule mangle sau:

    Code:
    /ip firewall mangle
    add chain=prerouting connection-mark=no-mark dst-address-type=!local  in-interface=bridge per-connection-classifier=both-addresses:3/0  action=mark-connection new-connection-mark=WAN1
    add chain=prerouting connection-mark=no-mark dst-address-type=!local  in-interface=bridge per-connection-classifier=both-addresses:3/1  action=mark-connection new-connection-mark=WAN2
    add chain=prerouting connection-mark=no-mark dst-address-type=!local  in-interface=bridge per-connection-classifier=both-addresses:3/2  action=mark-connection new-connection-mark=WAN3
    Với cc rule trn, chỉ đnh dấu (mark) cc traffic được chuyển tiếp từ mạng nội bộ LAN ra Internet, cc traffic từ mạng nội bộ LAN đến chnh router Mikrotik sẽ khng bị cc rule tc động (dst-address-type=!local). Cc kết nối (connection) sẽ được chia điều trn 3 kết nối WAN (load balancing) v được đnh dấu (new-connection-mark) với kết nối WAN tương ứng m connection sẽ đi ra Internet.

    Cc gi trị của trường per-connection-classifier=both-addresses lin quan đến biểu thức modular trong ton học, cc bạn c thể tm hiểu thm ở cc link cuối bi ny.

    Ch , mặc định th passthrough=yes được bật cho cc rule mangle ở trn. Tiếp theo, với cc kết nối đ được dnh dấu ở trn, chng ta cần đnh dấu routing mark kết nối được định tuyến theo đng bảng định tuyến m ta khai bao sau.

    Code:
    /ip firewall mangle
    add chain=prerouting  connection-mark=WAN1 in-interface=bridge action=mark-routing new-routing-mark=WAN1  passthrough=no
    add chain=prerouting  connection-mark=WAN2 in-interface=bridge action=mark-routing new-routing-mark=WAN2  passthrough=no
    add chain=prerouting  connection-mark=WAN3 in-interface=bridge action=mark-routing new-routing-mark=WAN3  passthrough=no
    Vậy traffic ở đy sẽ được balancing trn 3 kết nối WAN, với mỗi kết nối xuất pht từ mạng nội bộ LAN sẽ lần lược được điều hướng đến 3 bảng định tuyến WAN1, WAN2, WAN3 được khai bao bn dưới:

    Code:
    /ip route
    add dst-address=0.0.0.0/0  gateway=pppoe-out1 routing-mark=WAN1 
    add dst-address=0.0.0.0/0  gateway=pppoe-out2 routing-mark=WAN2
    add dst-address=0.0.0.0/0  gateway=pppoe-out3 routing-mark=WAN3
    Tiếp theo, chng ta cần khai bo cc route cho bảng định tuyến chnh (main) để cc traffic xuất pht từ chnh router c thể định tuyến ra ngoi Internet.

    Code:
    /ip route
    add dst-address=0.0.0.0/0  gateway=pppoe-out1 distance=1
    add dst-address=0.0.0.0/0  gateway=pppoe-out2 distance=2
    add dst-address=0.0.0.0/0  gateway=pppoe-out3 distance=2
    Đến đy, chng ta đ hon thnh việc cấu hnh load balancing v failover trn 3 kết nối WAN cho thiết bị router Mikrotik RB1100AHx2

  2. #2
    Administrator
    Join Date
    May 2015
    Posts
    66
    Bn dưới l 1 số hnh ảnh từ GUI winbox:
    1. Cc Interface của router Mikrotik RB1100AHx2



    2. Cc mangle rule trn router Mikrotik RB1100AHx2



    3. Bảng định tuyến trn router Mikrotik RB1100AHx2




    4. Cc địa chỉ IP cấp pht cho thiết bị di động, ở đy l 101 thiết bị đang hoạt động trn mạng



    Ti liệu tham khảo:
    - HowTo: Load Balancing multiple Internet connections
    - Bandwidth-based load-balancing with failover. The easy way
    - Load Balancing Using PCC & RouterOS
    - Load_balancing_multiple_same_subnet_links

    Bạn đọc c nhu cầu tư vấn, triển khai, hệ thống mạng khng dy quản l tập trung, wifi marketing, wifi hotspot cho doanh nghiệp, hệ thống mạng wifi cng cộng chịu tải cao... Lin hệ với chung ti theo thng tin sau:


    Cng ty Cổ phần CNTT Sao Thin Vương
    Website: http://switch-router.com/
    Email: info@switch-router.com
    Điện thoại: (08)38682371
    Hotline: 0917 39 7766

  3. #3
    Administrator
    Join Date
    May 2015
    Posts
    66
    Một cấu hnh load balancing, failover 2 WAN kết hợp NAT inbound cho cc ports 8000,88,554 trn router MikroTik thực tế tham khảo:

    Code:
    /ip firewall mangle
    add chain=prerouting dst-address=192.168.1.0/24 in-interface=bridge1
    add action=mark-connection chain=input connection-mark=no-mark in-interface=\
        pppoe-out1 new-connection-mark=WAN1 passthrough=no
    add action=mark-connection chain=input connection-mark=no-mark in-interface=\
        pppoe-out2 new-connection-mark=WAN2 passthrough=no
    add action=mark-routing chain=output connection-mark=WAN1 new-routing-mark=\
        WAN1 passthrough=no
    add action=mark-routing chain=output connection-mark=WAN2 new-routing-mark=\
        WAN2 passthrough=no
    add action=mark-connection chain=prerouting connection-state=new dst-port=\
        8000,88,554 in-interface=pppoe-out1 new-connection-mark=WAN1 passthrough=\
        no protocol=tcp
    add action=mark-connection chain=prerouting connection-state=new dst-port=\
        8000,88,554 in-interface=pppoe-out2 new-connection-mark=WAN2 passthrough=\
        no protocol=tcp
    add action=mark-connection chain=prerouting connection-mark=no-mark \
        dst-address-type=!local in-interface=bridge1 new-connection-mark=WAN1 \
        per-connection-classifier=both-addresses:2/0
    add action=mark-connection chain=prerouting connection-mark=no-mark \
        dst-address-type=!local in-interface=bridge1 new-connection-mark=WAN2 \
        per-connection-classifier=both-addresses:2/1
    add action=mark-routing chain=prerouting connection-mark=WAN1 in-interface=\
        bridge1 new-routing-mark=WAN1 passthrough=no
    add action=mark-routing chain=prerouting connection-mark=WAN2 in-interface=\
        bridge1 new-routing-mark=WAN2 passthrough=no
    /ip firewall nat
    add action=masquerade chain=srcnat out-interface=pppoe-out1
    add action=masquerade chain=srcnat out-interface=pppoe-out2
    add action=dst-nat chain=dstnat dst-address-type=local dst-port=88 protocol=\
        tcp to-addresses=192.168.1.200 to-ports=88
    add action=masquerade chain=srcnat dst-address=192.168.1.200 dst-port=88 \
        out-interface=bridge1 protocol=tcp src-address=192.168.1.0/24
    add action=dst-nat chain=dstnat dst-address-type=local dst-port=8000 \
        protocol=tcp to-addresses=192.168.1.200 to-ports=8000
    add action=masquerade chain=srcnat dst-address=192.168.1.200 dst-port=8000 \
        out-interface=bridge1 protocol=tcp src-address=192.168.1.0/24
    add action=dst-nat chain=dstnat dst-address-type=local dst-port=554 protocol=\
        tcp to-addresses=192.168.1.200 to-ports=554
    add action=masquerade chain=srcnat dst-address=192.168.1.200 dst-port=554 \
        out-interface=bridge1 protocol=tcp src-address=192.168.1.0/24

Tags for this Thread

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •